WaterMark/CMakeLists.txt

cmake_minimum_required(VERSION 3.10)

# set the project name
set (ProjectName WaterMark)
set (Version 2.1.0)

project(${ProjectName} VERSION ${Version})

set (DAEMON ${PROJECT_SOURCE_DIR}/../../daemon)
set (JPL_FILE_NAME ${ProjectName}.jpl)
set (DAEMON_SRC ${DAEMON}/src)
set (CONTRIB_PATH ${DAEMON}/contrib)
set (PLUGINS_LIB ${PROJECT_SOURCE_DIR}/../lib)
set (JPL_DIRECTORY ${PROJECT_BINARY_DIR}/jpl)
set (LIBS_DIR ${PROJECT_SOURCE_DIR}/../contrib/Libs)

if(WIN32)
    message(OS:\  WINDOWS\ ${CMAKE_SYSTEM_PROCESSOR})
    if (NOT ${CMAKE_CL_64})
        message( FATAL_ERROR "\nUse CMake only for x64 Windows" )
    endif()
    set (CONTRIB_PLATFORM_CURT x64)
    set (CONTRIB_PLATFORM ${CONTRIB_PLATFORM_CURT}-windows)
    set (LIBRARY_FILE_NAME ${ProjectName}.dll)
    set (FFMPEG ${CONTRIB_PATH}/build/ffmpeg/Build/win32/x64)
else()
    message( FATAL_ERROR "\nUse CMake only for Windows! For linux or Android (linux host), use our bash scripts." )
endif()

message(Building:\   ${ProjectName}\   ${Version})
message(Build\ path:\ ${PROJECT_BINARY_DIR})
message(JPL\ assembling\ path:\ ${JPL_DIRECTORY})
message(JPL\ path:\ ${JPL_DIRECTORY}/../../../build/${ProjectName}/${JPL_FILE_NAME})

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED True)

if(TESTPROCESS)
    set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /D__DEBUG__ /MD")
    set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /D__DEBUG__ /MD")
else()
    set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MD")
    set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MD")
endif()

set(plugin_SRC WatermarkVideoSubscriber.cpp
               main.cpp
               WatermarkMediaHandler.cpp
               PluginPreferenceHandler.cpp
               ./../lib/accel.cpp
               ./../lib/frameUtils.cpp
               ./../lib/frameFilter.cpp
               ./../lib/common.cpp
               )

set(plugin_HDR WatermarkVideoSubscriber.h
               WatermarkMediaHandler.h
               PluginPreferenceHandler.h
               ./../lib/accel.h
               ./../lib/frameUtils.h
               ./../lib/pluglog.h
               ./../lib/frameFilter.h
               ./../lib/mediaStream.h
               ./../lib/audioFormat.h
               ./../lib/common.h
               )

if(TESTPROCESS)
    add_executable(${ProjectName} ${plugin_SRC}
                                    ${plugin_HDR}
                                    )
else()
    add_library(${ProjectName} SHARED ${plugin_SRC}
                                        ${plugin_HDR}
                                        )
endif()

target_include_directories(${ProjectName} PUBLIC ${PROJECT_BINARY_DIR}
                                                 ${PROJECT_SOURCE_DIR}
                                                 ${PLUGINS_LIB}
                                                 ${DAEMON_SRC}
                                                 ${CONTRIB_PATH}
                                                 ${CONTRIB_PATH}/build/fmt/include
                                                 ${FFMPEG}/include
                                                 ${CONTRIB_PATH}/build/yaml-cpp/include
                                                 )
target_link_directories(${ProjectName} PUBLIC ${CONTRIB_PATH}
                                        ${FFMPEG}/lib
                                        ${CONTRIB_PATH}/msvc/lib/x64
                                        ${CONTRIB_PATH}/build/fmt/msvc/Release
                                        ${CONTRIB_PATH}/build/yaml-cpp/msvc/Release
                                        )

target_link_libraries(${ProjectName} PUBLIC libyaml-cppmd libavfilter libswscale libavformat libavcodec libavutil libvpx libx264 libopus libmfx
                                     freetype libzlib ws2_32 Bcrypt Secur32)

add_custom_command(
    TARGET ${ProjectName}
    PRE_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_directory ${PROJECT_SOURCE_DIR}/zlib ${CONTRIB_PATH}/src/zlib
    COMMAND ${CMAKE_COMMAND} -E copy_directory ${PROJECT_SOURCE_DIR}/../contrib/freetype ${CONTRIB_PATH}/src/freetype
    COMMAND ${CMAKE_COMMAND} -E copy_directory ${PROJECT_SOURCE_DIR}/ffmpeg/ ${CONTRIB_PATH}/src/ffmpeg
    COMMAND python ${DAEMON}/compat/msvc/winmake.py -fb zlib
    COMMAND python ${DAEMON}/compat/msvc/winmake.py -fb freetype
    COMMAND python ${DAEMON}/compat/msvc/winmake.py -fb ffmpeg
    COMMAND cd ${CONTRIB_PATH}/src/
    COMMAND git checkout *
)
if(TESTPROCESS)
    add_custom_command(
        TARGET ${ProjectName}
        PRE_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy ${PROJECT_SOURCE_DIR}/testPreferences.yml ${PROJECT_BINARY_DIR}/
        COMMAND ${CMAKE_COMMAND} -E copy ${PROJECT_SOURCE_DIR}/sample.mp4 ${PROJECT_BINARY_DIR}/
    )
else()
    add_custom_command(
        TARGET ${ProjectName}
        PRE_BUILD
        COMMAND python ${PROJECT_SOURCE_DIR}/../SDK/jplManipulation.py --preassemble --plugin=${ProjectName}
        COMMENT "Assembling Plugin files"
    )

    add_custom_command(
        TARGET ${ProjectName}
        POST_BUILD
        COMMAND ${CMAKE_COMMAND} -E copy ${PROJECT_BINARY_DIR}/Release/${ProjectName}.lib ${JPL_DIRECTORY}/lib/${CONTRIB_PLATFORM}
        COMMAND ${CMAKE_COMMAND} -E copy ${PROJECT_BINARY_DIR}/Release/${LIBRARY_FILE_NAME} ${JPL_DIRECTORY}/lib/${CONTRIB_PLATFORM}
        COMMAND python ${PROJECT_SOURCE_DIR}/../SDK/jplManipulation.py --assemble --plugin=${ProjectName}
        COMMENT "Generating JPL archive"
    )
endif()